SAK 図書館
SAK 図書館
VB oo4o + SQL 応用編9 oo4o ストアドファンクション - CreatePLSQLDynaset
oo4o は、Oracle RDBMS でみ使用可能です。
■ストアドパッケージ
・次のようにカーソルを返すストアドパッケージがあるとします。
これを CreatePLSQLDynaset で実行して、レコードセットを取得します。
(OraDynaset、カーソル取得)
create or replace package testp as
cursor c1 is select * from テストm;
type testmcu is ref cursor return c1%rowtype;
procedure GetTestm(key in varchar2, cu in out testmcu);
end;
/
create or replace package body testp is
procedure GetTestm(key in varchar2, cu in out testmcu) is
begin
open cu for select * from テストm where キー = key;
end;
end;
/
■現実的なコード例
Option Explicit
'** oo4o 変数宣言
dim OraSession
dim OraDatabase
dim qurs
'=======================================================================
' 準備
'=======================================================================
Private Sub Form_Load()
dim dbname as string
dim cnuser as string
'** エラートラップ開始
on local error resume next
'** アイキャッチ表示
'Load FormLogo
'FormLogo.Show
'DoEvents
'// 接続に 10 秒ほどかかるので、「データベース接続中...」などの
'// モードレスダイアログを表示すると良い。
'** サービス、ユーザ設定
dbname = ""
cnuser = "SAK/SAK"
'// Oracle サービス名(別名)、ユーザ・パスワード指定
'** oo4o 接続
Set OraSession = CreateObject("OracleInProcServer.XOraSession")
if err <> 0 then
MsgBox "データベースに接続出来ません。" & chr(10) _
& "CreateObject - Oracle oo4o エラー"
end
end if
Set OraDatabase = OraSession.OpenDatabase(dbname, cnuser, ORADB_DEFAULT)
if err <> 0 then
MsgBox "データベースに接続出来ません。" & chr(10) _
& err & ": " & error
end
end if
'** パラメタ追加
OraDatabase.Parameters.Add "キー", 0, ORAPARM_INPUT
OraDatabase.Parameters("キー").ServerType = ORATYPE_CHAR
if err <> 0 or OraDatabase.LastServerErr <> 0 then
MsgBox "パラメタ追加に失敗しました。" & chr(10) _
& err & ": " & error & chr(10) _
& "oo4o: " & OraDatabase.LastServerErrText
end
end if
'** リクエリレコードセットオープン
set qurs = OraDatabase.CreatePLSQLDynaset("Begin testp.GetTestm " _
& "(:キー, :cu); end;", "cu", ORADYN_DEFAULT)
if err <> 0 or OraDatabase.LastServerErr <> 0 then
MsgBox "リクエリレコードセットオープンに失敗しました。" & chr(10) _
& err & ": " & error & chr(10) _
& "oo4o: " & OraDatabase.LastServerErrText
end
end if
'** アイキャッチ終了
'Unload FormLogo
'// 接続が完了すれば、「データベース接続中...」をクローズする。
'** エラートラップ終了
on local error goto 0
End Sub
'=======================================================================
' 後始末
'=======================================================================
Private Sub Form_Unload(Cancel As Integer)
'** リクエリレコードセットクローズ
Set qurs = Nothing
'** パラメタ解消
OraDatabase.Parameters.Remove "キー"
'** oo4o 接続解除
Set OraDatabase = Nothing
Set OraSession = Nothing
End Sub
'=======================================================================
' メイン
'=======================================================================
Private Sub Command1_Click()
'** リクエリ
OraDatabase.Parameters("キー").value = "a001"
qurs.Refresh
if qurs.EOF then
print "a001 not found"
else
print qurs("キー")
end if
'** リクエリ
OraDatabase.Parameters("キー").value = "b002"
qurs.Refresh
if qurs.EOF then
print "b002 not found"
else
print qurs("キー")
end if
print "-- 終了 --"
End Sub
■VB oo4o + SQL 応用編資料
■VB ADO + SQL 応用編資料
■VB RDO + SQL 応用編資料
■SQL 基礎編資料
■SQL 基礎実地編資料
■SQL チューニング編資料
■Oracle PL/SQL 編資料
■PostgreSQL 編、JAVA Servlet、JSP 編資料
■MySQL 編資料
■VB 入門編資料
■VB 基礎編資料
■VB ビジュアル編資料
■VB テクニック編資料
Copyright (C) 1999-2018 Y.SAK