ASP VB Script oo4o + SQL 応用編7 oo4o 更新 - バッチ更新


\| VB \| SQL \| Perl \| PHP \| ASP \| JSP \| C \| PC \| HP \| FAQ \| フリーソフト \|

ASP VB Script oo4o + SQL 応用編7 oo4o 更新 - バッチ更新

oo4o は、Oracle RDBMS でみ使用可能です。

■CreateSql でのバッチ更新

  ・CreateSql で、バインド配列(OraParamArray)を使用してバッチ更新が
    できる。これは便利に使用できる。

■現実的なコード例

<%@ Language=VBScript %>
<%
'=======================================================================
'  準備
'=======================================================================
  Public Const ORADB_DEFAULT   = &H0
  Public Const ORASQL_DEFAULT     = &H0
  Public Const ORASQL_NO_AUTOBIND = &H1
  Public Const ORASQL_FAILEXEC    = &H2
  Public Const ORAPARM_INPUT    = 1
  Public Const ORAPARM_OUTPUT   = 2
  Public Const ORAPARM_BOTH     = 3
  Public Const ORATYPE_VARCHAR2 = 1
  Public Const ORATYPE_NUMBER   = 2
  Public Const ORATYPE_SINT     = 3
  Public Const ORATYPE_FLOAT    = 4
  Public Const ORATYPE_STRING   = 5
  Public Const ORATYPE_VARCHAR  = 9
  Public Const ORATYPE_DATE     = 12
  Public Const ORATYPE_UINT     = 68
  Public Const ORATYPE_CHAR     = 96
  Public Const ORATYPE_CHARZ    = 97
  Public Const ORATYPE_CURSOR   = 102
  dim dbname
  dim cnuser
  dim OraPArray(3)
  dim BachRowMax

'** エラートラップ開始
  on error resume next

'** サービス、ユーザ設定
  dbname = ""
  cnuser = "SAK/SAK"
  '// Oracle サービス名(別名)、ユーザ・パスワード指定

'** oo4o 接続
  if isempty(session("OraSession")) then
    Set session("OraSession") = Server.CreateObject("OracleInProcServer.XOraSession")
    if err <> 0 then
      response.write("<P>データベースに接続出来ません。<BR>" _
        & "CreateObject - Oracle oo4o エラー</P>")
    end if
  end if
  if isempty(session("OraDatabase")) then
    Set session("OraDatabase") = session("OraSession").OpenDatabase(dbname, cnuser, ORADB_DEFAULT)
    if err <> 0 then
      response.write("<P>データベースに接続出来ません。<BR>" _
        & err & ": " & error & "</P>")
    end if
  end if

'** パラメタ追加
  BachRowMax = 10
  if isempty(session("ParaAdd")) then
    session("OraDatabase").Parameters.AddTable "キー", ORAPARM_INPUT, ORATYPE_CHAR, BachRowMax, 4
    session("OraDatabase").Parameters.AddTable "データ1", ORAPARM_INPUT, ORATYPE_NUMBER, BachRowMax
    session("OraDatabase").Parameters.AddTable "データ2", ORAPARM_INPUT, ORATYPE_NUMBER, BachRowMax
    session("OraDatabase").Parameters.AddTable "データ3", ORAPARM_INPUT, ORATYPE_NUMBER, BachRowMax
    if err <> 0 or session("OraDatabase").LastServerErr <> 0 then
      response.write("<P>パラメタ追加に失敗しました。<BR>" _
        & err & ": " & error & "<BR>" _
        & "oo4o: " & session("OraDatabase").LastServerErrText & "</P>")
    else
      session("ParaAdd") = true
    end if
  end if

'** パラメタ配列準備
  set OraPArray(0) = session("OraDatabase").Parameters("キー")
  set OraPArray(1) = session("OraDatabase").Parameters("データ1")
  set OraPArray(2) = session("OraDatabase").Parameters("データ2")
  set OraPArray(3) = session("OraDatabase").Parameters("データ3")

'** エラートラップ終了
  on error goto 0

'=======================================================================
'  処理
'=======================================================================

'** RDB 処理
  if RdbShori() then
    response.write("<P>-- RDB 更新正常終了 (処理件数= " & session("OraSQLStmt").RecordCount & ") --</P>")
  end if

'=======================================================================
'  RDB 処理
'=======================================================================
function RdbShori()

  dim i

'** エラーセット
  RdbShori = FALSE

'** エラートラップ開始
  on error resume next

'** oo4o エラーリセット
  session("OraDatabase").LastServerErrReset

'** テストデータ作成
  for i = 0 to BachRowMax - 1
    OraPArray(0).Put_Value right("0000" & Int(Rnd(1) * 1000), 4), i
    OraPArray(1).Put_Value Int(Rnd(1) * 1000), i
    OraPArray(2).Put_Value Int(Rnd(1) * 1000), i
    OraPArray(3).Put_Value Int(Rnd(1) * 1000), i
  next

'** トランザクション開始
  session("OraSession").BeginTrans

'** RDB 処理1
  Set session("OraSQLStmt") = session("OraDatabase").CreateSql("insert into sak.テストm " _
    & "(キー, データ1, データ2, データ3) values " _
    & "(:キー, :データ1, :データ2, :データ3)", ORASQL_DEFAULT)
  if err <> 0 or session("OraDatabase").LastServerErr <> 0 then
    session("OraSession").Rollback
    response.write("<P>RDB 更新1 に失敗しました。<BR>" _
      & err & ": " & error & "<BR>" _
      & "oo4o: " & session("OraDatabase").LastServerErrText & "</P>")
    exit function
  end if

'** トランザクション終了
  session("OraSession").CommitTrans

'** エラートラップ終了
  on error goto 0

'** 正常セット
  RdbShori = TRUE

end function
%>

■説明

  ・Parameters.Add の代わりに Parameters.AddTable を使用して次元数を指定
    する。ここでは、BachRowMax = 10 を使用している。
    OraPArray と関連付けて、実際のデータをテストなので乱数でセット。
    CreateSql を実行すると、10 件の更新が行われる。

  ・OraPArray から、値を参照するには、Get_Value を使用する。
    OraPArray.LastErrorText もある。

■ASP VB Script oo4o + SQL 応用編資料

■ASP VB Script ADO + SQL 応用編資料

■ASP VB Script 基礎実地編資料

■ASP VB Script 基礎編資料

■SQL 基礎編資料

■SQL 基礎実地編資料

■SQL チューニング編資料

■Oracle PL/SQL 編資料

■PostgreSQL 編、JAVA Servlet、JSP 編資料

■MySQL 編資料


\| VB \| SQL \| Perl \| PHP \| ASP \| JSP \| C \| PC \| HP \| FAQ \| フリーソフト \|