ASP VB Script oo4o + SQL 応用編2 oo4o 接続 - CreateDatabasePool


\| VB \| SQL \| Perl \| PHP \| ASP \| JSP \| C \| PC \| HP \| FAQ \| フリーソフト \|

ASP VB Script oo4o + SQL 応用編2 oo4o 接続 - CreateDatabasePool

oo4o は、Oracle RDBMS でみ使用可能です。

■global.asa での oo4o 接続

<SCRIPT LANGUAGE=VBScript RUNAT=Server>
option explicit

Sub Application_OnStart

'** oo4o オブジォクト作成
  Set Application("OraSession") = Server.CreateObject("OracleInProcServer.XOraSession") 

End Sub

Sub Application_OnEnd

'** oo4o オブジォクト廃棄
  Set Application("OraSession") = Nothing

End Sub

Sub Session_OnStart

'** セッションタイムアウト
  Session.Timeout = 20

'** スクリプトタイムアウト
  Server.ScriptTimeout = 120

'** oo4o セッション作成
  Set Session("OraDatabase") = Application("OraSession").DbOpenDatabase("", "SAK/SAK", 0)

End Sub 

Sub Session_OnEnd

'** oo4o セッション廃棄
  Set Session("OraDatabase") = Nothing

End Sub

</SCRIPT>

■補足

  ・session("OraSession") については、application("OraSession") の方で
    定義してみた。

  ・この global.asa の定義を使用すると、asp では、
      application("OraSession")
      Session("OraDatabase")
    が使用できる。

■接続プールの使用

  ・接続プール使用は、旧バージョンの oo4o では自前で DLL を作成する。
    最近の oo4o では、CreateDatabasePool などが標準で使用できる。

<OBJECT RUNAT=Server SCOPE=Application ID=OraSession
  PROGID="OracleInProcServer.XOraSession">
</OBJECT>
<SCRIPT LANGUAGE=VBScript RUNAT=Server>
option explicit

Sub Application_OnStart

  const dbname = ""
  const cnuser = "SAK/SAK"

'** oo4o 接続プール作成
  OraSession.CreateDatabasePool 20, 100, 200, dbname, cnuser, 0
                               '|   |    |_ timeout seconds
                               '|   |_ max size
                               '|_ init size

End Sub

Sub Application_OnEnd

'** oo4o 接続プール廃棄
  OraSession.DestroyDatabasePool

End Sub

Sub Session_OnStart

'** セッションタイムアウト
  Session.Timeout = 20

'** スクリプトタイムアウト
  Server.ScriptTimeout = 120

'** oo4o セッション作成
  Set Session("OraDatabase") = OraSession.GetDatabaseFromPool(100)
                                                             '|_ wait time seconds

End Sub 

Sub Session_OnEnd

'** oo4o セッション廃棄
  Set Session("OraDatabase") = Nothing

End Sub

</SCRIPT>

■更新用特別セッションの使用

  ・接続プールを使用しての更新は、いろいろと問題があるようである。
    更新用特別セッションで処理するのが妥当らしい。

  const dbname = ""
  const cnuser = "SAK/SAK"

  Application.Lock
  Set oss = OraSession.Client.CreateSession("#" & Session.SessionID)
  Set odb = oss.OpenDatabase(dbname, cnuser, 0)
  Application.Unlock

  odb.BeginTrans

  odb.ExecuteSQL ...
  ... odb.Rollback

  odb.CommitTrans

  Application.Lock
  Set odb = Nothing
  Set oss = Nothing
  Application.Unlock

■ASP VB Script oo4o + SQL 応用編資料

■ASP VB Script ADO + SQL 応用編資料

■ASP VB Script 基礎実地編資料

■ASP VB Script 基礎編資料

■SQL 基礎編資料

■SQL 基礎実地編資料

■SQL チューニング編資料

■Oracle PL/SQL 編資料

■PostgreSQL 編、JAVA Servlet、JSP 編資料

■MySQL 編資料


\| VB \| SQL \| Perl \| PHP \| ASP \| JSP \| C \| PC \| HP \| FAQ \| フリーソフト \|