SAK 図書館
SAK 図書館
ASP VB Script 基礎実地編4 - データベース参照、項目名取得、項目タイプ判定
■データベース参照 - より良いコード
・項目名やデータタイプをデータベースから取得して表示に使用すると、
より汎用的なコードになる。
・次のコードでは、テーブル項目数や項目タイプが変わっても、同じコードで
自動的に表示することができる。
<%@ Language=VBScript %>
<%
const title = "データベース参照"
const dsn = "dsn=SAK3_ADO;uid=SAK;pwd=SAK"
const dcr = 3 '** adUseClient
const dbi = "*"
const dbf = "sak.テストm"
const dbw = "" '** where キー like 'a%'
const dbo = "order by キー"
dim sql, rs, ct, tdal, i, s
'** データベース接続
if isempty(session("s3cn_ado")) then
set session("s3cn_ado") = server.CreateObject ("ADODB.Connection")
session("s3cn_ado").Open dsn
session("s3cn_ado").CursorLocation = dcr
end if
'** クエリ発行
sql = "select " & dbi & " from " & dbf & " " & dbw & " " & dbo
set rs = session("s3cn_ado").Execute(sql)
%>
<HTML>
<HEAD>
<TITLE><% = title %></TITLE>
</HEAD>
<BODY>
<%
'** データリストアップ
response.write("<P>")
response.write("<TABLE rules=ALL bgcolor=#b0b0b0 border=0 cellPadding=3 cellSpacing=2><TBODY>")
response.write("<TR bgcolor=#d0d0d0>")
response.write("<TD>リスト番号</TD>")
for i = 0 to rs.fields.count - 1
response.write("<TD>" & rs(i).name & "</TD>")
next
response.write("</TR>")
ct = 0
do until rs.eof
ct = ct + 1
s = right("000000" & ct, 6)
response.write("<TR bgcolor=#f0f0f0>")
response.write("<TD>" & s & "</TD>")
for i = 0 to rs.fields.count - 1
if rs(i).type <> 131 and rs(i).type <> 139 then
tdal = ""
else
tdal = " align=right"
end if
response.write("<TD" & tdal & ">" & rs(i) & "</TD>")
next
response.write("</TR>")
rs.movenext
loop
response.write("</TBODY></TABLE>")
response.write("</P>")
'** レコードセットクローズ
rs.close
%>
</BODY>
</HTML>
■ASP VB Script 基礎実地編資料
■ASP VB Script 基礎編資料
■ASP VB Script ADO + SQL 応用編資料
■ASP VB Script oo4o + SQL 応用編資料
■SQL 基礎編資料
■SQL 基礎実地編資料
■SQL チューニング編資料
■Oracle PL/SQL 編資料
■PostgreSQL 編、JAVA Servlet、JSP 編資料
■MySQL 編資料
Copyright (C) 1999-2018 Y.SAK