1. よねさんのExcelとWordの使い方 » 
2. エクセル2010 練習問題 » 
3. 行と列の検索索

エクセル2010練習問題：行と列の検索索

• 問題1の解答例　　　　topへ

  
  

  	B	C	D	E	F	G	H
  2		鹿児島	鹿児島北	薩摩吉田	姶良	加治木	溝辺鹿児島空港
  3	鹿児島	-	250	300	600	850	1,050
  4	鹿児島北	250	-	300	600	850	1,050
  5	薩摩吉田	300	300	-	350	600	800
  6	姶良	600	600	350	-	350	600
  7	加治木	850	850	600	350	-	350
  8	溝辺鹿児島空港	1,050	1,050	800	600	350	-
  9	料金	850
  10	出発IC	鹿児島北
  11	到着IC	加治木

  1. INDEX関数とMATCH関数で一致する行と列を調べて求めることができます。
     • 構文：=INDEX(範囲,行番号,列番号)
       INDEX関数　に説明がありますので参照してください。
     • 構文：=MATCH(検索値,範囲 [,照合の型])
       MATCH関数　に説明がありますので参照してください。
     • 出発IC「C10セル」と一致する行は　MATCH(C10,B3:B8,0)　で求めます。
       到着IC「C11セル」と一致する行は　MATCH(C11,C2:H2,0)　で求めます。
     • 料金は　=INDEX(C3:H8,MATCH(C10,B3:B8,0),MATCH(C11,C2:H2,0))　で求めることができます。
  2. VLOOKUP関数を主に使って求めることもできます。
     • 構文：=VLOOKUP(検索値,範囲,列番号,[検索の型])
       VLOOKUP関数　に説明がありますので参照してください。
     • =VLOOKUP(C10,B3:H8,MATCH(C11,B2:H2,0),FALSE)　となります。
       • VLOOKUP関数の範囲がB3:H8、MATCH関数の範囲がB2:H2となっていますのでご注意ください。
  3. HLOOKUP関数を主に使って求めることもできます。
     • 構文：=HLOOKUP(検索値,範囲,行番号,[検索の型])
       HLOOKUP関数　に説明がありますので参照してください。
     • =HLOOKUP(C11,B2:H8,MATCH(C10,B2:B8,0),FALSE)　となります。

• 問題2の解答例　　　　topへ

  • B20セルには　=INDEX(C4:N15,SUMPRODUCT((A4:A15=B17)*(B4:B15=B19)*ROW(A1:A12)),MATCH(B18,C3:N3,0))　と入力しました。
    
  • INDEX関数で行位置と列位置を求めることができれば、上記の問題1と同じように計算ができます。
    =INDEX(C4:N15,行位置、列位置)
  • 行位置に2つの条件が有るので、行位置を求めるためにはSUMPRPDUCT関数が利用できます。
    SUMPRODUCT((A4:A15=B17)*(B4:B15=B19)*ROW(A1:A12))　としています。
    (A4:A15=B17)*(B4:B15=B19)　とすることで、一致したところがTRUEとなりますので、行位置の1〜12を掛け合わせるようにして、
    SUMPRODUCT((A4:A15=B17)*(B4:B15=B19)*ROW(A1:A12))　で求めることができます。
    B17セルが「2012年」、B19セルが「降灰量」と入力されている場合は、下表のように計算されます。
    行位置「9」が得られることになります。(ワークシートではTRUE=1、FALSE=0　として計算されます)

    	(A4:A15=B17)		(B4:B15=B19)	ROW(A1:A12))	SUMPRODUCT((A4:A15=B17)*(B4:B15=B19)*ROW(A1:A12))
    	2012年		降灰量
    2010年	FALSE	噴火	FALSE	1	FALSE*FALSE*1=0*0*1=0
    2010年	FALSE	爆発	FALSE	2	FALSE*FALSE*2=0*0*2=0
    2010年	FALSE	降灰量	TRUE	3	FALSE*TRUE*3=0*1*3=0
    2011年	FALSE	噴火	FALSE	4	FALSE*FALSE*4=0*0*4=0
    2011年	FALSE	爆発	FALSE	5	FALSE*FALSE*5=0*0*5=0
    2011年	FALSE	降灰量	TRUE	6	FALSE*TRUE*6=6=0*1*70
    2012年	TRUE	噴火	FALSE	7	TRUE*FALSE*7=1*0*7=0
    2012年	TRUE	爆発	FALSE	8	TRUE*FALSE*8=1*0*8=0
    2012年	TRUE	降灰量	TRUE	9	TRUE*TRUE*9=1*1*9=9
    2013年	FALSE	噴火	FALSE	10	FALSE*FALSE*10=0*0*10=0
    2013年	FALSE	爆発	FALSE	11	FALSE*FALSE*11=0*0*11=0
    2013年	FALSE	降灰量	TRUE	12	FALSE*TRUE*12=0*1*12=0

  • 列位置はMATCH関数で　MATCH(B18,C3:N3,0)求　として、求めることができます。

スポンサードリンク