1. よねさんのExcelとWordの使い方 » 
2. エクセル2010 練習問題 » 
3. 順位の計算

エクセル2010練習問題：順位の計算

• 問題1の解答例　　　　topへ

  
  

  	B	C	D	E
  2	名前	性別	得点	順位
  3	相沢一郎	男	52	7
  4	井上浩二	男	74	5
  5	上野有紀	女	84	1
  6	内野武	男	77	2
  7	上田祥子	女	68	6
  8	江田早苗	女	77	2
  9	榎本高貴	男	77	2
  10	小田和樹	男	47	8

  1. 数式の例：順位はRANK関数で求めることができます。
     • 構文：=RANK(数値,範囲,[順序])
       順序に0を入れるか、省略すると降順での順位になります。
       0以外の数値を入れると昇順での順位になります。
       RANK関数　に説明がありますので参照してください。
     • RANK関数の「範囲」は不動ですので絶対参照にしておいて、E3の数式を下方向へコピーします。

     	B	C	D	E
     2	名前	性別	得点	順位
     3	相沢一郎	男	52	=RANK(D3,$D$3:$D$10)
     4	井上浩二	男	74	=RANK(D4,$D$3:$D$10)
     5	上野有紀	女	84	=RANK(D5,$D$3:$D$10)
     6	内野武	男	77	=RANK(D6,$D$3:$D$10)
     7	上田祥子	女	68	=RANK(D7,$D$3:$D$10)
     8	江田早苗	女	77	=RANK(D8,$D$3:$D$10)
     9	榎本高貴	男	77	=RANK(D9,$D$3:$D$10)
     10	小田和樹	男	47	=RANK(D10,$D$3:$D$10)

  2. Excel2010ではRANK.EQ関数が使用できます。
     E3セルは　=RANK.EQ(D3,$D$3:$D$10)　となります。
     • 構文：RANK.EQ(数値,範囲,[順序])
  3. 求めたい得点よりも大きな値が何個あるか調べれば、求めたい得点の順位はその個数+1となります。
     よって　=COUNTIF($D$3:$D$10,">"&D3)+1　でも求めることができます。
     • 構文：=COUNTIF(範囲,検索条件)
       COUNTIF関数　に説明がありますので参照してください。
     • COUNTIF関数の検索条件で比較演算子とセル参照を組み合わせて使う時は比較演算子とセル参照を&でつなぎます。

• 問題2の解答例　　　　topへ

  
  

  	B	C	D	E
  2	名前	性別	得点	順位
  3	相沢一郎	男	52	7
  4	井上浩二	男	74	5
  5	上野有紀	女	84	1
  6	内野武	男	77	2
  7	上田祥子	女	68	6
  8	江田早苗	女	77	3
  9	榎本高貴	男	77	4
  10	小田和樹	男	47	8

  1. 数式の例：同点が上のデータにあるか否かをCOUNTIF関数で調べます。
     同点が2個あれば、2つ目の同点者はRANK関数で求めた順位+1　となりますので、+COUNTIF($D$3:D3,D3)-1　と補正します。
     この問題では絶対参照の使い方がポイントと考えます。
     • 構文：=COUNTIF(範囲,検索条件)
       COUNTIF関数　に説明がありますので参照してください。

     	B	C	D	E
     2	名前	性別	得点	順位
     3	相沢一郎	男	52	=RANK(D3,$D$3:$D$10)+COUNTIF($D$3:D3,D3)-1
     4	井上浩二	男	74	=RANK(D4,$D$3:$D$10)+COUNTIF($D$3:D4,D4)-1
     5	上野有紀	女	84	=RANK(D5,$D$3:$D$10)+COUNTIF($D$3:D5,D5)-1
     6	内野武	男	77	=RANK(D6,$D$3:$D$10)+COUNTIF($D$3:D6,D6)-1
     7	上田祥子	女	68	=RANK(D7,$D$3:$D$10)+COUNTIF($D$3:D7,D7)-1
     8	江田早苗	女	77	=RANK(D8,$D$3:$D$10)+COUNTIF($D$3:D8,D8)-1
     9	榎本高貴	男	77	=RANK(D9,$D$3:$D$10)+COUNTIF($D$3:D9,D9)-1
     10	小田和樹	男	47	=RANK(D10,$D$3:$D$10)+COUNTIF($D$3:D10,D10)-1

  2. 作業列を使ってもよいケースでは行番号を補正値に利用した作業列を設けます。
     • E3セルに　=D3-ROW()/100　と入力し、E10セルまでコピーしました。
       • 行番号が小さいほど大きな値になるように行番号の 1/100 の値を得点から引いて補正しました。
         行番数が99までは有効ですが、100〜999のデータのときは1/1000など得点の最小値1に影響を与えないようにする必要があります。
     • 構文ROW([範囲])
       範囲を省略すると、ROW 関数が入力されているセルの行番号が返されます。
       ROW・ROWS関数　に説明がありますので参照してください。

     	B	C	D	E	F
     2	名前	性別	得点	作業列	順位
     3	相沢一郎	男	52	51.97	=RANK(E3,$E$3:$E$10)
     4	井上浩二	男	74	73.96	=RANK(E4,$E$3:$E$10)
     5	上野有紀	女	84	83.95	=RANK(E5,$E$3:$E$10)
     6	内野武	男	77	76.94	=RANK(E6,$E$3:$E$10)
     7	上田祥子	女	68	67.93	=RANK(E7,$E$3:$E$10)
     8	江田早苗	女	77	76.92	=RANK(E8,$E$3:$E$10)
     9	榎本高貴	男	77	76.91	=RANK(E9,$E$3:$E$10)
     10	小田和樹	男	47	46.9	=RANK(E10,$E$3:$E$10)

• 問題3の解答例　　　　topへ

  
  

  • 	B	C	D	E	F	G	H
    2	名前	性別	得点	順位		順位	名前
    3	相沢一郎	男	52	7		1位	上野有紀
    4	井上浩二	男	74	5		2位	内野武
    5	上野有紀	女	84	1		3位	江田早苗
    6	内野武	男	77	2		4位	榎本高貴
    7	上田祥子	女	68	6
    8	江田早苗	女	77	3
    9	榎本高貴	男	77	4
    10	小田和樹	男	47	8

  • 数式の例：この解答例では1,2,3・・・という数値をROW(A1)で代用しています。
    • 3位の得点は　LARGE($D$3:$D$10,3)　で求めることができます。
      • 構文：=LARGE(範囲,順位)
        LARGE関数　に説明がありますので参照してください。
    • 3位の得点以上は何名いるかを調べます。
      COUNTIF($D$3:$D$10,">="&LARGE($D$3:$D$10,3)
    • これで表示する対象者の数がわかりますので、
      G3セル以降に=IF((COUNTIF($D$3:$D$10,">="&LARGE($D$3:$D$10,3))>=ROW(A1)),ROW(A1)&"位","")
      として、このケースでは1位〜4位と順位を表示します。
    • H列の名前はE列の順位と一致する行の名前を書き出すのでINDEX関数で求めました。
      • 構文：=INDEX(範囲,行番号,[列番号],[領域番号])
        INDEX関数　に説明がありますので参照してください。
      • 構文：=MATCH(検査値,検査範囲,[照合の型])
        MATCH関数　に説明がありますので参照してください。
      =IF(H3="","",INDEX($B$3:$B$10,MATCH(ROW(A1),$F$3:$F$10,0)))
  • 3位との同点までが5人いたら下図のように5位まで表示されます。
    この例では赤丸の得点を変更しています。
    
  • 同点者がいないときは3位までが表示されます。
    この例では赤丸の得点を変更しています。
    

スポンサードリンク