1. よねさんのExcelとWordの使い方 » 
2. エクセル2010 練習問題 » 
3. 条件の判定

エクセル2010練習問題：条件の判定

• 問題1の解答例　　　　topへ

  
  

  	B	C	D	E
  2	名前	性別	得点	判定
  3	相沢一郎	男	52	×
  4	井上浩二	男	74	○
  5	上野有紀	女	84	○
  6	内野武	男	77	○
  7	上田祥子	女	68	×
  8	江田早苗	女	59	×
  9	榎本高貴	男	77	○
  10	小田和樹	男	47	×

  • 数式の例：条件の判定にはIF関数が使えます。
    • 構文：=IF(論理式,[真の場合],[偽の場合])
      IF関数　に説明がありますので参照してください。

    	B	C	D	E
    2	名前	性別	得点	判定
    3	相沢一郎	男	52	=IF(D3>=70,"○","×")
    4	井上浩二	男	74	=IF(D4>=70,"○","×")
    5	上野有紀	女	84	=IF(D5>=70,"○","×")
    6	内野武	男	77	=IF(D6>=70,"○","×")
    7	上田祥子	女	68	=IF(D7>=70,"○","×")
    8	江田早苗	女	59	=IF(D8>=70,"○","×")
    9	榎本高貴	男	77	=IF(D9>=70,"○","×")
    10	小田和樹	男	47	=IF(D10>=70,"○","×")

• 問題2の解答例　　　　topへ

  
  

  	B	C	D	E
  2	名前	性別	得点	判定
  3	相沢一郎	男	52	可
  4	井上浩二	男	74	良
  5	上野有紀	女	84	優
  6	内野武	男	77	良
  7	上田祥子	女	68	可
  8	江田早苗	女	59	可
  9	榎本高貴	男	77	良
  10	小田和樹	男	47	不

  1. 数式の例：複数の条件はIF関数をネストして書くことができます。
     

     	B	C	D	E
     2	名前	性別	得点	判定
     3	相沢一郎	男	52	=IF(D3>=80,"優",IF(D3>=70,"良",IF(D3>=50,"可","不")))
     4	井上浩二	男	74	=IF(D4>=80,"優",IF(D4>=70,"良",IF(D4>=50,"可","不")))
     5	上野有紀	女	84	=IF(D5>=80,"優",IF(D5>=70,"良",IF(D5>=50,"可","不")))
     6	内野武	男	77	=IF(D6>=80,"優",IF(D6>=70,"良",IF(D6>=50,"可","不")))
     7	上田祥子	女	68	=IF(D7>=80,"優",IF(D7>=70,"良",IF(D7>=50,"可","不")))
     8	江田早苗	女	59	=IF(D8>=80,"優",IF(D8>=70,"良",IF(D8>=50,"可","不")))
     9	榎本高貴	男	77	=IF(D9>=80,"優",IF(D9>=70,"良",IF(D9>=50,"可","不")))
     10	小田和樹	男	47	=IF(D10>=80,"優",IF(D10>=70,"良",IF(D10>=50,"可","不")))

  2. 満たした条件数で数値化して求めることもできます。
     • =(D3>0)+(D3>=50)+(D3>=70)+(D3>=80)　と条件を満たしたら加算するようにします。
       1のときは「不」、2のときは「可」、3のときは「良」、4のときは「優」となるようにします。
       • =MID("不可良優",(D3>0)+(D3>=50)+(D3>=70)+(D3>=80),1)
         MID関数　に説明がありますので参照してください。
       • =INDEX({"不","可","良","優"},(D3>0)+(D3>=50)+(D3>=70)+(D3>=80))
         INDEX関数　に説明がありますので参照してください。
       • =VLOOKUP((D3>0)+(D3>=50)+(D3>=70)+(D3>=80),{1,"不";2,"可";3,"良";4,"優"},2)
         VLOOKUP関数　に説明がありますので参照してください。

• 問題3の解答例　　　　topへ

  
  

  	B	C	D
  2	試験日	得点	判定
  3	2011/7/1	66
  4	2011/7/2	71	合格
  5	2011/8/4	78
  6	2011/8/5	69
  7	2011/8/6	84	合格
  8	2011/8/7	79
  9	2011/9/1	72	合格
  10	2011/9/2	68

  • 数式の例
    • 月数と得点の2つがAND条件となりますので、AND(月数の条件,得点の条件）とします。
      与えられた条件を問題文の通りに並べて書くと・・・
      =IF(AND(MONTH(B3)=7,C3>=70),"合格",IF(AND(MONTH(B3)=8,C3>=80),"合格",IF(AND(MONTH(B3)=9,C3>=70),"合格","")))
    • 「合格」とする条件に着目すると、各月の条件はOR条件なので
      =IF(OR(AND(MONTH(B3)=7,C3>=70),AND(MONTH(B3)=8,C3>=80),AND(MONTH(B3)=9,C3>=70)),"合格","")
      とまとめることができます。

スポンサードリンク