エクセル2010練習問題：データのカウント

スポンサードリンク

問題　　　　topへ

問題1：受験者数と欠席者数を求めなさい。　　問題1の解答

	B	C	D	E	F
2	名前	性別	1回目のテスト		受験者数
3	相沢一郎	男	52
4	井上浩二	男	74		欠席者数
5	上野有紀	女	欠席
6	内野武	男	35
7	上田祥子	女	欠席
8	江田早苗	女	59
9	榎本高貴	男	0
10	小田和樹	男	47

問題2：合格者の数を求めなさい。　　問題2の解答

	B	C	D	E	F
2	名前	性別	判定		合格者の数
3	相沢一郎	男	不合格
4	井上浩二	男	合格
5	上野有紀	女	合格
6	内野武	男	合格
7	上田祥子	女	合格
8	江田早苗	女	不合格
9	榎本高貴	男	合格
10	小田和樹	男	不合格

問題3：男の合格者数を求めなさい。　　問題3の解答

	B	C	D	E	F
2	名前	性別	判定		男の合格者の数
3	相沢一郎	男	不合格
4	井上浩二	男	合格
5	上野有紀	女	合格
6	内野武	男	合格
7	上田祥子	女	合格
8	江田早苗	女	不合格
9	榎本高貴	男	合格
10	小田和樹	男	不合格

解答例　　　　topへ

問題1の解答例　　　　 topへ

	B	C	D	E	F
2	名前	性別	1回目のテスト		受験者数
3	相沢一郎	男	52		6
4	井上浩二	男	74		欠席者数
5	上野有紀	女	欠席		2
6	内野武	男	35
7	上田祥子	女	欠席
8	江田早苗	女	59
9	榎本高貴	男	0
10	小田和樹	男	47

データのどこに着目するかで、色々な数式が考えられます。

受験者には得点(数値)が入力されていて、欠席者には「欠席」と文字列が入力されていると、判断しました。

数値の数をカウントするにはCOUNT関数が使えます。
受験者数は　=COUNT(D3:D10)　で求めることができます。
- 構文：=COUNT(値1,[値2],・・・)
  COUNT関数に説明がありますので参照してください。
欠席者数は「欠席」という文字の入力されているセル数を数えればよいので、COUNTIF関数が使えます。
欠席者数は　=COUNTIF(D3:D10,"欠席")　で求めることができます。
- 構文：=COUNTIF(範囲,検索条件)
  COUNTIF関数に説明がありますので参照してください。

	B	C	D	E	F
2	名前	性別	1回目のテスト		受験者数
3	相沢一郎	男	52		=COUNT(D3:D10)
4	井上浩二	男	74		欠席者数
5	上野有紀	女	欠席		=COUNTIF(D3:D10,"欠席")
6	内野武	男	35
7	上田祥子	女	欠席
8	江田早苗	女	59
9	榎本高貴	男	0
10	小田和樹	男	47

受験者と欠席者とを合わせた数はCOUNTA関数で求めることができます。
この値から、受験者数を差し引いたものが欠席者となるので、
欠席者は　=COUNTA(D3:D10)-COUNT(D3:D10)　として求めることもできます。
- 構文：構文：=COUNTA(値1,[値2],・・・)
  COUNTA関数に説明がありますので参照してください。
上のBとは逆に全員の数から欠席者の数を差し引いて受験者数を求める・・・といった考え方もできます。
- 受験者数　=COUNTA(D3:D10)-COUNTIF(D3:D10,"欠席")
- 欠席者数　=COUNTIF(D3:D10,"欠席")

問題2の解答例　　　 topへ

	B	C	D	E	F
2	名前	性別	判定		合格者の数
3	相沢一郎	男	不合格		5
4	井上浩二	男	合格
5	上野有紀	女	合格
6	内野武	男	合格
7	上田祥子	女	合格
8	江田早苗	女	不合格
9	榎本高貴	男	合格
10	小田和樹	男	不合格

「合格」と入力されたセルの数をカウントするのは、COUNTIF関数で求めることができます。

構文：=COUNTIF(範囲,検索条件)
COUNTIF関数に説明がありますので参照してください。

	B	C	D	E	F
2	名前	性別	判定		合格者の数
3	相沢一郎	男	不合格		=COUNTIF(D3:D10,"合格")
4	井上浩二	男	合格
5	上野有紀	女	合格
6	内野武	男	合格
7	上田祥子	女	合格
8	江田早苗	女	不合格
9	榎本高貴	男	合格
10	小田和樹	男	不合格

SUMPRODUCT関数を使って求めることもできます。
=SUMPRODUCT((D3:D10="合格")*1)
- 構文：=SUMPRODUCT(配列1,[配列2],[配列3],・・・)
  SUMPRODUCT関数　に説明がありますので参照してください。
- 上記の式では　(D3:D10="合格")　の部分は{FALSE;TRUE;TRUE;TRUE;TRUE;FALSE;TRUE;FALSE}と論理値になるので、*1で数値化しています。
  (TRUE)*1=1、(FALSE)*1=0　の結果を合計しています。

問題3の解答例　　　　 topへ

	B	C	D	E	F
2	名前	性別	判定		男の合格者の数
3	相沢一郎	男	不合格		3
4	井上浩二	男	合格
5	上野有紀	女	合格
6	内野武	男	合格
7	上田祥子	女	合格
8	江田早苗	女	不合格
9	榎本高貴	男	合格
10	小田和樹	男	不合格

複数条件のカウントはCOUNTIFS関数で求めることができます。（Excel2007以降で使用できます）

構文：COUNTIFS(条件範囲1,検索条件1,[条件範囲2,検索条件2]・・・)
COUNTIFS関数に説明がありますので参照してください。

	B	C	D	E	F
2	名前	性別	判定		男の合格者の数
3	相沢一郎	男	不合格		=COUNTIFS(C3:C10,"男",D3:D10,"合格")
4	井上浩二	男	合格
5	上野有紀	女	合格
6	内野武	男	合格
7	上田祥子	女	合格
8	江田早苗	女	不合格
9	榎本高貴	男	合格
10	小田和樹	男	不合格

SUMPRODUCT関数を使って求めることもできます。
- =SUMPRODUCT((C3:C10="男")*(D3:D10="合格"))
- 構文：=SUMPRODUCT(配列1,[配列2],[配列3],・・・)
  SUMPRODUCT関数に説明がありますので参照してください。
- または、　=SUMPRODUCT((C3:C10&D3:D10="男合格")*1)　といった式でも求めることができます。

検索条件をシートに書き出すことで、データベース関数が利用できます。
この問題ではDCOUNTA関数を使うことができます。

構文：=DCOUNTA(データベース,フィールド,検索条件)
DCOUNTA関数に説明がありますので参照してください。

検索条件をG2:H2に入力した例です。
F3セルは　=DCOUNTA(C2:D10,1,G2:H3)　としました。

	B	C	D	E	F	G	H
2	名前	性別	判定		男の合格者の数	性別	判定
3	相沢一郎	男	不合格		=DCOUNTA(C2:D10,1,G2:H3)	男	合格
4	井上浩二	男	合格
5	上野有紀	女	合格
6	内野武	男	合格
7	上田祥子	女	合格
8	江田早苗	女	不合格
9	榎本高貴	男	合格
10	小田和樹	男	不合格

作業列を利用すると容易な数式になります。

E列を作業列として、E3セルに以下のように入力します。
=IF(AND(C3="男",D3="合格"),1,"0")
男の合格者には「1」が入力されるので、=SUM(E3:E10)　で求めることができます。

	B	C	D	E	F
2	名前	性別	判定	作業列	男の合格者の数
3	相沢一郎	男	不合格	0	=SUM(E3:E10)
4	井上浩二	男	合格	1
5	上野有紀	女	合格	0
6	内野武	男	合格	1
7	上田祥子	女	合格	0
8	江田早苗	女	不合格	0
9	榎本高貴	男	合格	1
10	小田和樹	男	不合格	0

スポンサードリンク

よねさんのExcelとWordの使い方｜エクセル2010 練習問題：目次｜データのカウント